Tune Brudmarsch från Nås
Download as ABC · PDF · MIDI
Play MIDIPlease make it stop
PauseResume
N.B. MIDI is a terrible way to learn a fiddle tune!
This beautiful tune appears in my book Swedish Fiddle Music, an Anthology, and featured on the accompanying cassette which is now available for download. Or you can download just this track.
This tune appears in these collections: Broadstairs, 2012 · Whitby, 2012 · Newhaven, 2023
Trad arr. © 2012 Ben Paley
Generating the image...
ShowHide ABC
%%abc-version 2.1
%%abc-copyright (C) Copyright Ben Paley 2026
%%writefields N
%%writefields D
%%measurenb 0
%%partsbox 1
X:1
T:Brudmarsch från Nås
T:Wedding March from Nås
L:1/8
M:2/4
C:Trad arr. © 2012 Ben Paley
N:This beautiful tune appears in my book "Swedish Fiddle Music, an Anthology" available from
N:www.lulu.com/spotlight/SwedishFiddleMusic/
N:It also featured on the accompanying cassette which is now available for download from my
N:Bandcamp page: benpaley-fiddle.bandcamp.com/
O:Sweden
R:March
Z:Ben Paley <ben.paley@benpaley.com>
K:Gm
V:M clef=treble name="Melody" snm="M"
V:H clef=treble name="Harmony" snm="H"
%%score M|H
P:A
[V:M]|: D^F GA | B2 B2 | AG Ac | cd d2 | dc AB |
[V:H]|: G,A, B,D | G2 G2 | DC D^F | AB B2 | BA ^FG |
[V:M] G2 BA | ^FD FA |1 AG =EG | ^F2 D2 :|2 G3 A/2B/2 | GA Bc |
[V:H] D2 G^F | DA, D^F |1 ^F=E C=E | D2 A,2 :|2 D3 ^F/2G/2 | D^F GA |
P:B
[V:M][| d2 Bd | dc A2 | c2 Ac | cB G2 |
[V:H][| B2 GB | BA ^F2 | A2 ^FA | AG D2 |
[V:M] B2 AG | ^FD FA | AG =EG | ^F2 D2 |
[V:H] G2 ^F=E | DA, D^F | ^F=E C=E | D2 A,2 |
[V:M] d2 Bd | dc A2 | c2 Ac | cB G2 |
[V:H] B2 GB | BA ^F2 | A2 ^FA | AG D2 |
[V:M] B2 AG | ^FD FA | G3 A/2B/2 | GA Bc |
[V:H] G2 ^F=E | DA, D^F | D3 ^F/2G/2 | D^F GA |
[V:M] d2 Bd | dc A2 | c2 Ac | cB G2 |
[V:H] B2 GB | BA F2 | A2 FA | AG D2 |
[V:M] B2 AG | ^FD FA | AG =EG | ^F2 D2 |
[V:H] G2 ^F=E | DA, D^F | ^F=E C=E | D2 A,2 |
[V:M] d2 Bd | dc A2 | c2 Ac | cB G2 |
[V:H] B2 FB | BA F2 | A2 FA | AG D2 |
[V:M] B2 AG | ^FD FA | G3 A/2B/2 | G4 |]
[V:H] G2 ^F=E | DA, D^F | D3 ^F/2G/2 | D4 |]